@echo off
chcp 65001 > nul

set "RimWorldFolder=C:\Program Files (x86)\Steam\steamapps\common\RimWorld"
set "ModsFolder=%RimWorldFolder%\Mods"
set "TempFolder=%SystemDrive%\Temp\RimWorld\PerformanceFish"
set LimitDownloads=true
set "LimitDownloadsFolder=%TempFolder%\Logs\LimitDownloads_OnceADay"
set "LimitDownloadsFile=%LimitDownloadsFolder%\%date%.txt"
set DelConfigWhenUpdate=true
set "ConfigFolder=%UserProfile%\AppData\LocalLow\Ludeon Studios\RimWorld by Ludeon Studios\Config"
set "ConfigFile=%ConfigFolder%\Mod_Performance-Fish-main_PerformanceFishMod.xml"

if not exist "%RimWorldFolder%\Mods" (
echo Not found Mods folder in RimWorld folder.
pause & exit
)

if not exist "%TempFolder%\New" md "%TempFolder%\New"
if not exist "%TempFolder%\Old" md "%TempFolder%\Old"
if not exist "%LimitDownloadsFolder%" md "%LimitDownloadsFolder%"

if %LimitDownloads%==true if exist "%LimitDownloadsFile%" if exist "%TempFolder%\New\PerformanceFish.zip" if exist "%TempFolder%\New\Fishery.zip" goto SkipDownload

curl -L -o "%TempFolder%\New\PerformanceFish.zip" "https://github.com/bbradson/Performance-Fish/archive/master.zip" >nul 2>nul
curl -L -o "%TempFolder%\New\Fishery.zip" "https://github.com/bbradson/Fishery/archive/master.zip" >nul 2>nul
if %errorlevel%==0 (
(echo=) > "%LimitDownloadsFile%"
)

:SkipDownload

:CheckPerformanceFish

if not exist "%TempFolder%\Old\PerformanceFish.zip" goto UpdatePerformanceFish
if not exist "%ModsFolder%\Performance-Fish-main" goto UpdatePerformanceFish

for %%q in ("%TempFolder%\New\PerformanceFish.zip") do set NewFileSize=%%~zq
for %%q in ("%TempFolder%\Old\PerformanceFish.zip") do set OldFileSize=%%~zq
if not "%NewFileSize%"=="%OldFileSize%" goto UpdatePerformanceFish

goto CheckFishery

:UpdatePerformanceFish

rd /s /q "%ModsFolder%\Performance-Fish-main"
powershell -command "Expand-Archive '%TempFolder%\New\PerformanceFish.zip' '%ModsFolder%'"

if "%DelConfigWhenUpdate%"=="true" del /q "%ConfigFile%"

copy /y "%TempFolder%\New\PerformanceFish.zip" "%TempFolder%\Old"

:CheckFishery

if not exist "%TempFolder%\Old\Fishery.zip" goto UpdateFishery
if not exist "%ModsFolder%\Fishery-main" goto UpdateFishery

for %%q in ("%TempFolder%\New\Fishery.zip") do set NewFileSize=%%~zq
for %%q in ("%TempFolder%\Old\Fishery.zip") do set OldFileSize=%%~zq
if not "%NewFileSize%"=="%OldFileSize%" goto UpdateFishery

goto End

:UpdateFishery

rd /s /q "%ModsFolder%\Fishery-main"
powershell -command "Expand-Archive '%TempFolder%\New\Fishery.zip' '%ModsFolder%'"

copy /y "%TempFolder%\New\Fishery.zip" "%TempFolder%\Old"

:End

exit